home *** CD-ROM | disk | FTP | other *** search
/ BCI NET 2 / BCI NET 2.iso / archives / programming / source / a2.0bemacs-src.lha / Emacs-19.25 / lisp / find-dired.el < prev    next >
Encoding:
Text File  |  1994-05-04  |  8.6 KB  |  241 lines
  1. ;;; find-dired.el --- run a `find' command and dired the output
  2.  
  3. ;;; Copyright (C) 1992, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Roland McGrath <roland@gnu.ai.mit.edu>,
  6. ;;       Sebastian Kremer <sk@thp.uni-koeln.de>
  7. ;; Maintainer: Sebastian Kremer <sk@thp.uni-koeln.de>
  8. ;; Keywords: unix
  9.  
  10. (defconst find-dired-version (substring "$Revision: 1.16 $" 11 -2)
  11.   "$Id: find-dired.el,v 1.16 1994/05/03 23:39:55 kwzh Exp $")
  12.  
  13. ;;; This program is free software; you can redistribute it and/or modify
  14. ;;; it under the terms of the GNU General Public License as published by
  15. ;;; the Free Software Foundation; either version 1, or (at your option)
  16. ;;; any later version.
  17. ;;;
  18. ;;; This program is distributed in the hope that it will be useful,
  19. ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20. ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21. ;;; GNU General Public License for more details.
  22. ;;;
  23. ;;; A copy of the GNU General Public License can be obtained from this
  24. ;;; program's author (send electronic mail to roland@ai.mit.edu) or from
  25. ;;; the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA
  26. ;;; 02139, USA.
  27. ;;;
  28.  
  29. ;;; Commentary:
  30.  
  31. ;; LISPDIR ENTRY for the Elisp Archive ===============================
  32. ;;    LCD Archive Entry:
  33. ;;    find-dired|Roland McGrath, Sebastian Kremer
  34. ;;    |roland@gnu.ai.mit.edu, sk@thp.uni-koeln.de
  35. ;;    |Run a `find' command and dired the output
  36. ;;    |$Date: 1994/05/03 23:39:55 $|$Revision: 1.16 $|
  37.  
  38. ;; INSTALLATION ======================================================
  39.  
  40. ;; To use this file, byte-compile it, install it somewhere in your
  41. ;; load-path, and put:
  42.  
  43. ;;   (autoload 'find-dired "find-dired" nil t)
  44. ;;   (autoload 'find-name-dired "find-dired" nil t)
  45. ;;   (autoload 'find-grep-dired "find-dired" nil t)
  46.  
  47. ;; in your ~/.emacs, or site-init.el, etc.
  48.  
  49. ;; To bind it to a key, put, e.g.:
  50. ;;
  51. ;;   (global-set-key "\C-cf" 'find-dired)
  52. ;;   (global-set-key "\C-cn" 'find-name-dired)
  53. ;;   (global-set-key "\C-cl" 'find-grep-dired)
  54. ;;
  55. ;; in your ~/.emacs.
  56.  
  57. ;;; Code:
  58.  
  59. (require 'dired)
  60.  
  61. ;;;###autoload
  62. (defvar find-ls-option (if (eq system-type 'berkeley-unix) "-ls"
  63.              "-exec ls -ldi {} \\;")
  64.   "*Option to `find' to produce an `ls -l'-type listing.")
  65.  
  66. ;;;###autoload
  67. (defvar find-grep-options (if (eq system-type 'berkeley-unix) "-s" "-l")
  68.   "*Option to grep to be as silent as possible.
  69. On Berkeley systems, this is `-s', for others it seems impossible to
  70. suppress all output, so `-l' is used to print nothing more than the
  71. file name.")
  72.  
  73. (defvar find-args nil
  74.   "Last arguments given to `find' by \\[find-dired].")
  75.  
  76. ;;;###autoload
  77. (defun find-dired (dir args)
  78.   "Run `find' and go into dired-mode on a buffer of the output.
  79. The command run (after changing into DIR) is
  80.  
  81.     find . \\( ARGS \\) -ls"
  82.   (interactive (list (read-file-name "Run find in directory: " nil "" t)
  83.              (if (featurep 'gmhist)
  84.              (read-with-history-in 'find-args-history
  85.                            "Run find (with args): ")
  86.                (read-string "Run find (with args): " find-args))))
  87.   ;; Expand DIR ("" means default-directory), and make sure it has a
  88.   ;; trailing slash.
  89.   (setq dir (file-name-as-directory (expand-file-name dir)))
  90.   ;; Check that it's really a directory.
  91.   (or (file-directory-p dir)
  92.       (error "find-dired needs a directory: %s" dir))
  93.   (switch-to-buffer (get-buffer-create "*Find*"))
  94.   (widen)
  95.   (kill-all-local-variables)
  96.   (setq buffer-read-only nil)
  97.   (erase-buffer)
  98.   (setq default-directory dir
  99.     find-args args            ; save for next interactive call
  100.     args (concat "find . "
  101.              (if (string= args "")
  102.              ""
  103.                (concat "\\( " args " \\) "))
  104.              find-ls-option))
  105.   ;; The next statement will bomb in classic dired (no optional arg allowed)
  106.   ;; find(1)'s -ls corresponds to these switches.
  107.   ;; Note -b, at least GNU find quotes spaces etc. in filenames
  108.   (dired-mode dir "-gilsb")
  109.   ;; Set subdir-alist so that Tree Dired will work:
  110.   (if (fboundp 'dired-simple-subdir-alist)
  111.       ;; will work even with nested dired format (dired-nstd.el,v 1.15
  112.       ;; and later)
  113.       (dired-simple-subdir-alist)
  114.     ;; else we have an ancient tree dired (or classic dired, where
  115.     ;; this does no harm) 
  116.     (set (make-local-variable 'dired-subdir-alist)
  117.      (list (cons default-directory (point-min-marker)))))
  118.   (setq buffer-read-only nil)
  119.   ;; Subdir headlerline must come first because the first marker in
  120.   ;; subdir-alist points there.
  121.   (insert "  " dir ":\n")
  122.   ;; Make second line a ``find'' line in analogy to the ``total'' or
  123.   ;; ``wildcard'' line. 
  124.   (insert "  " args "\n")
  125.   ;; Start the find process
  126.   (set-process-filter (start-process-shell-command "find"
  127.                            (current-buffer) args)
  128.               (function find-dired-filter))
  129.   (set-process-sentinel (get-buffer-process (current-buffer))
  130.             (function find-dired-sentinel))
  131.   (setq mode-line-process '(":%s")))
  132.  
  133. ;;;###autoload
  134. (defun find-name-dired (dir pattern)
  135.   "Search DIR recursively for files matching the globbing pattern PATTERN,
  136. and run dired on those files.
  137. PATTERN is a shell wildcard (not an Emacs regexp) and need not be quoted.
  138. The command run (after changing into DIR) is
  139.  
  140.     find . -name 'PATTERN' -ls"
  141.   (interactive
  142.    "DFind-name (directory): \nsFind-name (filename wildcard): ")
  143.   (find-dired dir (concat "-name '" pattern "'")))
  144.  
  145. ;; This functionality suggested by
  146. ;; From: oblanc@watcgl.waterloo.edu (Olivier Blanc)
  147. ;; Subject: find-dired, lookfor-dired
  148. ;; Date: 10 May 91 17:50:00 GMT
  149. ;; Organization: University of Waterloo
  150.  
  151. (defalias 'lookfor-dired 'find-grep-dired)
  152. ;;;###autoload
  153. (defun find-grep-dired (dir args)
  154.   "Find files in DIR containing a regexp ARG and start Dired on output.
  155. The command run (after changing into DIR) is
  156.  
  157.     find . -exec grep -s ARG {} \\\; -ls
  158.  
  159. Thus ARG can also contain additional grep options."
  160.   (interactive "DFind-grep (directory): \nsFind-grep (grep args): ")
  161.   ;; find -exec doesn't allow shell i/o redirections in the command,
  162.   ;; or we could use `grep -l >/dev/null'
  163.   (find-dired dir
  164.           (concat "! -type d -exec grep " find-grep-options " "
  165.               args " {} \\\; ")))
  166.  
  167. (defun find-dired-filter (proc string)
  168.   ;; Filter for \\[find-dired] processes.
  169.   (let ((buf (process-buffer proc)))
  170.     (if (buffer-name buf)        ; not killed?
  171.     (save-excursion
  172.       (set-buffer buf)
  173.       (save-restriction
  174.         (widen)
  175.         (save-excursion
  176.           (let ((buffer-read-only nil)
  177.             (end (point-max)))
  178.         (goto-char end)
  179.         (insert string)
  180.         (goto-char end)
  181.         (or (looking-at "^")
  182.             (forward-line 1))
  183.         (while (looking-at "^")
  184.           (insert "  ")
  185.           (forward-line 1))
  186.         ;; Convert ` ./FILE' to ` FILE'
  187.         ;; This would lose if the current chunk of output
  188.         ;; starts or ends within the ` ./', so backup up a bit:
  189.         (goto-char (- end 3))    ; no error if < 0
  190.         (while (search-forward " ./" nil t)
  191.           (delete-region (point) (- (point) 2)))))))
  192.       ;; The buffer has been killed.
  193.       (delete-process proc))))
  194.  
  195. (defun find-dired-sentinel (proc state)
  196.   ;; Sentinel for \\[find-dired] processes.
  197.   (let ((buf (process-buffer proc)))
  198.     (if (buffer-name buf)
  199.     (save-excursion
  200.       (set-buffer buf)
  201.       (let ((buffer-read-only nil))
  202.         (save-excursion
  203.           (goto-char (point-max))
  204.           (insert "\nfind " state)
  205.           (forward-char -1)        ;Back up before \n at end of STATE.
  206.           (insert " at " (substring (current-time-string) 0 19))
  207.           (forward-char 1)
  208.           (setq mode-line-process
  209.             (concat ":"
  210.                 (symbol-name (process-status proc))))
  211.           ;; Since the buffer and mode line will show that the
  212.           ;; process is dead, we can delete it now.  Otherwise it
  213.           ;; will stay around until M-x list-processes.
  214.           (delete-process proc)
  215.           ;; Force mode line redisplay soon.
  216.           (set-buffer-modified-p (buffer-modified-p))))
  217.       (message "find-dired %s finished." (current-buffer))))))
  218.  
  219. (or (fboundp 'start-process-shell-command)
  220.     ;; From version 19 subr.el.
  221. (defun start-process-shell-command (name buffer &rest args)
  222.   "Start a program in a subprocess.  Return the process object for it.
  223. Args are NAME BUFFER COMMAND &rest COMMAND-ARGS.
  224. NAME is name for process.  It is modified if necessary to make it unique.
  225. BUFFER is the buffer or (buffer-name) to associate with the process.
  226.  Process output goes at end of that buffer, unless you specify
  227.  an output stream or filter function to handle the output.
  228.  BUFFER may be also nil, meaning that this process is not associated
  229.  with any buffer
  230. Third arg is command name, the name of a shell command.
  231. Remaining arguments are the arguments for the command.
  232. Wildcards and redirection are handled as usual in the shell."
  233.   (if (eq system-type 'vax-vms)
  234.       (apply 'start-process name buffer args)
  235.     (start-process name buffer shell-file-name "-c"
  236.            (concat "exec " (mapconcat 'identity args " "))))))
  237.  
  238. (provide 'find-dired)
  239.  
  240. ;;; find-dired.el ends here
  241.